Domino Migration mit encrypted Mails

Sub Click(Source As Button)


'''''''''''''''''''''''''''''''''''''''''''''''''''''
' Script Contakt
' Migriert die lokalen Kontakte aus der Names.nsf in das bestehende Outlook Profil über eine Button Mail!
' Wurde noch nicht mit allen Versionen getestet. welche Felder nicht migriert werden können, kann der Tabelle entnommen werden.
' Anlagen in Kontakte werden nicht migriert. Gruppen werden ebenfalls nicht migriert. Emailadressen die nicht dem SMTP Standard entspechen, werden eins zu eins übernommen
'
' Beschreibung
'
' Version: 1.0
' Datum:   15.09.2006
' Autor:   Heinz Kröwing
' Letzte Änderungen:
'
' Heinz Kröwing stellt dieses Skript ohne jede
' Gewährleistung zur Verfügung.
' Die Verwendung geschieht auf eigene Gefahr.
'
'''''''''''''''''''''''''''''''''''''''''''''''''''''	


	Dim session As New notessession
	Dim db As notesdatabase
	  ' Abfrage auf das lokale names.nsf
	Set db = session.GetDatabase( "", "names.nsf" )
	Dim doc As notesdocument
	
	Dim view As notesview
	Set view= db.getview ("People")
	
	     ' Setzt die Outlook Object
	Set Application = CreateObject("Outlook.Application")	
	Set mName = Application.GetNameSpace("MAPI")
	Set mOrdner = mName.GetDefaultFolder(10)
	Set mFeld = Application.CreateItem(2)
	
	Set doc = view.getfirstdocument
	
	Do While Not (doc Is Nothing) 
		Set mFeld = Application.CreateItem(2)     		
		With mFeld 
			.FullName =doc.FirstName(0) + " " + doc.MiddleInitial(0) + " " + doc.LastName(0)
			If (doc.Suffix(0) <> "0") Then .Suffix=doc.Suffix(0)
			If (doc.Title(0) <> "0") Then .Title=doc.Title(0)
			.JobTitle=doc.JobTitle(0)
			.CompanyName=doc.CompanyName(0)
			.BusinessTelephoneNumber=doc.OfficePhoneNumber(0)
			.BusinessFaxNumber=doc.OfficeFaxPhoneNumber(0)
			.MobileTelephoneNumber=doc.CellPhoneNumber(0)
			.CarTelephoneNumber=doc.PersPager(0)
			.Email1Address=doc.MailAddress(0)
			.Email2Address=doc.MiscPhone1(0)
			.Email3Address=doc.MiscPhone2(0)
			.WebPage=doc.WebSite(0)
			If (doc.Birthday(0) <> " " And doc.Birthday(0) <> "") Then .Birthday=doc.Birthday(0)  
			.PagerNumber=doc.PhoneNumber_6(0)
			.HomeTelephoneNumber=doc.PhoneNumber(0)
			.HomeAddressStreet=doc.StreetAddress(0)
			.HomeAddressPostalCode=doc.Zip(0)
			.HomeAddressCity=doc.City(0)
			.HomeAddressCountry=doc.Country(0)
			.HomeAddressState=doc.State(0)
			.HomeFaxNumber=doc.HomeFaxPhoneNumber(0)
			.BusinessAddressStreet=doc.OfficeStreetAddress(0)
			.BusinessAddressPostalCode=doc.OfficeZip(0)
			.BusinessAddressCity=doc.OfficeCity(0)
			.BusinessAddressCountry=doc.OfficeCountry(0)
			.BusinessAddressState=doc.OfficeState(0)
			.Spouse=doc.Spouse(0)
			.Children=doc.Children(0)
			.AssistantName=doc.Assistant(0)
			.ManagerName=doc.Manager(0)
			.OfficeLocation=doc.Location(0)
			.Department=doc.Department(0)
			.Categories=doc.Categories(0)			
	'.=doc.Briefcase(0)
	'.=doc.Comment(0)
	'.=doc.MiscPhone3(0)
			.save	
		End With
		
		Set doc = view.getnextdocument(doc)
	Loop
	Application.quit	
End Sub