hallo zusammen
genial dass ich so rasch eine reaktion bekomme vielen dank!
also ich habe einen dc mit 2003 den ich aber nicht migrieren will sondern ich stelle einen neuen dc rein und einzig die daten plus postfächer werde ich dann importieren, der rest geht auf den müll.
ich habe auf vm workstation nun meine win2008enterprise x64 (nicht r2) deutsch installiert und alles ging wie bitter, hab da noch ein paar andere server am laufen die alle bisher einwandfrei funktionieren...
nun habe ich den folgenden batch laufen lassen und gedacht das wär's und ich könne das setup laufen lassen... scheint sich wohl doch vieles verändert zu haben zu 2003.
nun habe ich habe im geposteten link gesehen dass ich wohl noch folgende befehle vergessen habe und ausfürhen muss:
setup.com /PrepareSchema
setup.com /PrepareAD /OrganizationName:MEINORGANISATIONSNAME
setup.com /PrepareDomain
sehe ich das richtig? dann sollte auch nicht mehr so komisches zeugs kommen wie in den angehängten grafiken?
würdet ihr gleich exchange 2010 installieren (in scharfe und produktive umgebung) oder doch besser 2007 um sicher zu gehen dass es rund läuft?
stehe tierisch unter zeitdruck und kann mir leider kaum mehr was erlauben da in 10 tagen alles ready sein muss... aber eben, bin ja selber schuld auf den letzten drücker alles zu machen 
vielen dank für eure feedbacks und beste grüsse
switzerland
hier übrigens noch den batch den ich im internet gefunden habe um windows 2008 vorzubereiten, ein grosser dank an den fleissigen programmierer:
@echo off
rem Installieren der Voraussetzungen fuer Exchange 2007 SP1
rem auf Windows Server 2008
rem vgl. http://technet.microsoft.com/e…y/bb691354(EXCHG.80).aspx
rem Ordner fuer Logging setzen: Skriptordner
rem Achtung: Nach den zwei Punkten darf kein Leerzeichen stehen!
set folder=%0\..
:web-mgmt
if exist %folder%\web-mgmt.txt goto powershell
echo --- Installiere Web-Management-Voraussetzungen ...
ServerManagerCmd -i Web-Metabase
ServerManagerCmd -i Web-Lgcy-Mgmt-Console
echo web-mgmt OK>%folder%\web-mgmt.txt
rem *** mehrere Rollen (CAS, Hub, MB, UM)
:powershell
if exist %folder%\powershell.txt goto iis
echo --- Installiere PowerShell ...
ServerManagerCmd -i PowerShell
echo PowerShell OK>%folder%\powershell.txt
rem *** mehrere Rollen (CAS, MB)
:iis
if exist %folder%\iis.txt goto rpc
echo --- Installiere IIS-Komponenten ...
ServerManagerCmd -i Web-Server
ServerManagerCmd -i Web-ISAPI-Ext
ServerManagerCmd -i Web-Metabase
ServerManagerCmd -i Web-Lgcy-Mgmt-Console
ServerManagerCmd -i Web-Basic-Auth
ServerManagerCmd -i Web-Digest-Auth
ServerManagerCmd -i Web-Windows-Auth
ServerManagerCmd -i Web-Dyn-Compression
echo IIS OK>%folder%\iis.txt
rem *** CAS-Rolle
:rpc
if exist %folder%\rpc-proxy.txt goto desktop
echo --- Installiere OL Anywhere ...
ServerManagerCmd -i RPC-over-HTTP-proxy
echo rpc-proxy OK>%folder%\rpc-proxy.txt
rem *** UM-Rolle
:desktop
if exist %folder%\desktop-exp.txt goto rsat
echo --- Installiere Media-Extensions ...
ServerManagerCmd -i Desktop-Experience
echo Desktop-Exp OK>%folder%\desktop-exp.txt
echo.
echo ACHTUNG: Neustart erforderlich! Bitte danach das Batch neu starten!
echo.
echo Starte neu ...
shutdown -r -d p:2:4 /c "Desktop Experience installiert"
rem *** alle Rollen
:rsat
if exist %folder%\rsat-adds.txt goto fertig
echo --- Installiere AD-Verwaltungstool (RSAT-ADDS) ...
ServerManagerCmd -i RSAT-ADDS
rem Neustart erforderlich, daher Flagdatei schreiben
echo RSAT-ADDS OK>%folder%\rsat-adds.txt
echo.
echo ACHTUNG: Neustart erforderlich! Danach ist die Installation abgeschlossen.
echo.
echo Starte neu ...
shutdown -r -d p:2:4 /c "RSAT-ADDS installiert"
:fertig
echo.
echo --- Fertig!
pause
